Otherware/Otherware_1_SB_Development.iso/mac/util/comm/arapp144.sit/Practical 14400FXSA-no retrain

Text File | 1992-08-06 | 5.2 KB | 258 lines

! "Practical Peripherals PM14400FXSA- no retrain - 8/6/92"
!  by SBM  CompuServe ID: 72711,2044 (daily) or 74435,357 (occasional)
!          GENIE: S.MEUSE2 (occasional)
!          AppleLink: CYTYC.DEV (daily)
!          Internet: [e-mail]
!
! Non-commercial distribution of non-beta versions is encouraged provided
! the files are unmodified and all files are included in the distribution.
! Please report any problems.  Thanks!
!
! This script REQUIRES a hardware handshaking cable.  Practical Peripherals
! and MacConnection sell ones known to work correctly.
!
! revision history
! 1.0B1- 5/8/92-
!    Initial beta release. Uploaded to CompuServe's PPIFORUM only.
! 1.0B2- 6/23/92-
!    Not released. Local testing only.
!    Ñ Fixed bug where script wasn't respecting the modem's CS line.
!    Ñ Looking into bugs reported with this script at both ends @ 14400bps.
!      I did duplicate this, and it appears to be due to an acknowledged
!      incompatibility between ARA 1.0 and Apple Internet Router 2.0.
! 1.0B3- 7/6/92-
!    Released via email to a few beta sites for testing only.
! 1.0B4- 7/10/92-
!    Second general beta release. Uploaded to CompuServe's PPIFORUM only.
! 1.0B4, "no retrain"- 7/10/92-
!    added &B0 and S110=1.
! 1.0B5- 7/28/92-
!    local testing only.  Wait 90 seconds after dial for carrier.
! 1.0- 8/6/92-
!    Initial general release.  Uploaded to PPIFORUM, MACCOM, GEnie, & the PPI BBS.
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 19200, 0, 8, 1
!
! first recall the factory configuration
!
matchclr
settries 0
matchstr 1 3 "OK\13\10"
@LABEL 2
write "AT&F\13"
matchread 30
inctries
iftries 2 59
jump 2
!
! then echo off, DTR off, enable the modem's RTS/CTS flow control
@LABEL 3
matchclr
matchstr 1 4 "OK\13\10"
write "ATE0&C1&D0&K3\13"
matchread 30
jump 59
!
! then turn off error correction, use autospeed buffering,
! turn off V.32 auto retrain,
! configure CONNECT messages to report DCE speed instead of DTE
! allow 90 seconds for a successful connection (up from 50).
!
@LABEL 4
matchclr
matchstr 1 5 "OK\13\10"
matchstr 2 5 "ERROR\13\10"
write "AT&Q6&B0S110=1W2S7=90\13"
matchread 30
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
@LABEL 5
ifstr 2 8 "1"
matchclr
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATS0=0DT^1\13"
!
@LABEL 9
matchclr
matchstr  1 11 "CONNECT 1200\13\10"
matchstr  2 12 "CONNECT 2400\13\10"
matchstr  3 13 "CONNECT 4800\13\10"
matchstr  4 14 "CONNECT 7200\13\10"
matchstr  5 15 "CONNECT 9600\13\10"
matchstr  6 16 "CONNECT 12000\13\10"
matchstr  7 17 "CONNECT 14400\13\10"
matchstr  8 18 "CONNECT 19200\13\10"
matchstr  9 50 "NO CARRIER\13\10"
matchstr 10 50 "ERROR\13\10"
matchstr 11 52 "NO DIALTONE\13\10"
matchstr 12 53 "BUSY\13\10"
matchstr 13 54 "NO ANSWER\13\10"
matchread 999
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
CommunicatingAt 1200
jump 19
!
@LABEL 12
note "Communicating at 2400 bps." 2
CommunicatingAt 2400
jump 19
!
@LABEL 13
note "Communicating at 4800 bps." 2
CommunicatingAt 4800
jump 19
!
@LABEL 14
note "Communicating at 7200 bps." 2
CommunicatingAt 7200
jump 19
!
@LABEL 15
note "Communicating at 9600 bps." 2
CommunicatingAt 9600
jump 19
!
@LABEL 16
note "Communicating at 12 kbps." 2
CommunicatingAt 12000
jump 19
!
@LABEL 17
note "Communicating at 14.4 kbps." 2
CommunicatingAt 14400
jump 19
!
@LABEL 18
note "Communicating at 19.2 kbps." 2
CommunicatingAt 19200
!
! enable RTS/CTS handshaking at the serial port
!
@LABEL 19
HSReset 0 1 0 0 0 0
ifANSWER 20
pause 30
@LABEL 20
exit 0
!
! @ANSWER
! Set up modem to answer
@LABEL 30
matchclr
matchstr 1 31 "OK\13\10"
write "ATS0=1\13"
matchread 30
jump 59
!
@LABEL 31
matchclr
matchstr  1 32 "RING\13\10"
matchstr  2 11 "CONNECT 1200\13\10"
matchstr  3 12 "CONNECT 2400\13\10"
matchstr  4 13 "CONNECT 4800\13\10"
matchstr  5 14 "CONNECT 7200\13\10"
matchstr  6 15 "CONNECT 9600\13\10"
matchstr  7 16 "CONNECT 12000\13\10"
matchstr  8 17 "CONNECT 14400\13\10"
matchstr  9 18 "CONNECT 19200\13\10"
matchstr 10 50 "NO CARRIER\13\10"
matchstr 11 50 "ERROR\13\10"
matchstr 12 52 "NO DIALTONE\13\10"
matchstr 13 53 "BUSY\13\10"
matchstr 14 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone╔" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! turn off RTS/CTS at serial port, hang up the modem
!
@HANGUP
@LABEL 60
HSReset 0 0 0 0 0 0
settries 0
@LABEL 61
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 64 "ERROR\13\10"
write "ATH0\13"
matchread 15
inctries
iftries 3 64
! no response, try escape sequence
matchclr
matchstr 1 62 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
write "+++"
matchread 18
! No response from modem, try reset command
write "ATZ\13"
pause 30
jump 61
!
@LABEL 62
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
write "ATH0\13"
matchread 50
jump 61
!
@LABEL 63
pause 45
flush
!
! recall the factory settings
!
@LABEL 64
matchclr
matchstr 1 65 "OK\13\10"
write "AT&F\13"
matchread 30
!
@LABEL 65
matchclr
matchstr 1 66 "OK\13\10"
write "ATS0=0\13"
matchread 30
!
@LABEL 66
exit 0